# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=termcap
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=1.3.1
pkgrel=2
pkgdesc="Terminal feature database (mingw-w64)"
arch=('any')
url="ftp://ftp.gnu.org/gnu/termcap/"
license=("GPL" "LGPL")
makedepends=("${MINGW_PACKAGE_PREFIX}-gcc")
depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
options=('staticlibs' 'strip')
source=("http://ftp.gnu.org/gnu/termcap/${_realname}-${pkgver}.tar.gz")
md5sums=('ffe6f86e63a3a29fa53ac645faaabdfa')

prepare() {
  cd "${srcdir}/${_realname}-${pkgver}"
  autoconf
}

build() {
  [ -d ${srcdir}/build-${MINGW_CHOST} ] && rm -rf ${srcdir}/build-${MINGW_CHOST}
  mkdir ${srcdir}/build-${MINGW_CHOST}
  cd ${srcdir}/build-${MINGW_CHOST}

  ../${_realname}-${pkgver}/configure \
    --prefix=${MINGW_PREFIX} \
    --build=${MINGW_CHOST} \
    --host=${MINGW_CHOST} \
    --target=${MINGW_CHOST}

  make
  # Build a shared library.  No need for -fPIC on Windows.
  ${MINGW_PREFIX}/bin/gcc -shared \
    -Wl,--out-implib,libtermcap.dll.a \
    -o libtermcap-0.dll \
    termcap.o tparam.o version.o
}

package() {
  cd  ${srcdir}/build-${MINGW_CHOST}
  make install prefix="${pkgdir}${MINGW_PREFIX}" exec_prefix="${pkgdir}${MINGW_PREFIX}" oldincludedir=
  rm -r "${pkgdir}"${MINGW_PREFIX}/info/
  mkdir -p "${pkgdir}"${MINGW_PREFIX}/{bin,lib}
  install -m 0755 libtermcap-0.dll "${pkgdir}${MINGW_PREFIX}/bin"
  install -m 0644 libtermcap.dll.a "${pkgdir}${MINGW_PREFIX}/lib"
}
